Re: A way to highlight 32F line?

Hi Cory,

This question should be posted to ncl-talk, so I've CC'ed that group.

Adam Phillips just recently answered a similar question about changing the line color for a certain contour line, and the same principles apply.

Here's a sample code that changes the line thickness for contour level 32 (using dummy data):

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

begin
; Create some dummy data.
  data = generate_2d_array(10, 10, 0., 128, 0, (/100,100/))

  wks = gsn_open_wks("x11","coneff")

  res = True
  res@gsnMaximize = True ; Maximize plot in frame.

  res@cnLevelSelectionMode = "ExplicitLevels"
  res@cnLevels = ispan(0,128,16)
;
; By default, all lines will be the same thickness. You need to
; set this "Mono" resource to False to tell NCL you want varying
; line thicknesses.
;
  res@cnMonoLineThickness = False
  res@cnLineThicknesses = (/1.,1.,2.,1.,1.,1.,1.,1.,1./) ; make 32 2x thick

  contour = gsn_csm_contour(wks,data,res)
end

--Mary

On Jan 10, 2011, at 4:07 PM, Cory Van Pelt wrote:

> Hi Everyone,
>
> I know there's a function to highlight a "zero" line in NCL, but is there a way to have it draw a double-thickness line for 32 F?
>
> Thanks!
>
> Cory Van Pelt
> NWS Juneau, AK
>
> _______________________________________________
> ncarg-talk mailing list
> ncarg-talk@ucar.edu
> http://mailman.ucar.edu/mailman/listinfo/ncarg-talk

_______________________________________________
ncarg-talk mailing list
ncarg-talk@ucar.edu
http://mailman.ucar.edu/mailman/listinfo/ncarg-talk
Received on Tue Jan 11 07:59:11 2011